further — 7 of 11

Chapter 3 - Remembering

Section 1 - Memories

A memory is a kind of thing.

A memory can be visited or unvisited. A memory is usually unvisited.

A memory has a room called a target.

A memory has a region called a home.

A memory has a color.

A memory has some text called realization. The realization of a memory is usually "This was something from your life.".

a ruddy bell is a wearable red memory. Understand "collar" and "dog collar" as bell.

bell is in Foggy Room. The description of bell is "[if unvisited]a bell[else]Alice's bell[end if]".

The target of bell is Wine Cellar.

The home of bell is Brick.

The realization of the bell is "The surreal brick room around you shimmers into a suburban basement. You remember that the bell was once part of the collar for your dog, Alice. She died when you were... seven? Yes. You remember the weight of her pressed against your legs.".

Ringing is an action applying to one thing.

Understand "ring [something]" as ringing.

Carry out ringing:

if noun is bell:

say "Dong....";

else:

say "The [noun] can't ring.".

a jaundiced penny is a yellow memory.

penny is in Alcove. The description of penny is "[if unvisited]a penny[else]Alan's penny[end if]".

The target of penny is Dunes. The home of penny is Desert.

The realization of the penny is "Alan gave you this. Alan was your... husband? Yes. Bemused in groups, serious when alone.".

a cobalt ribbon is a wearable blue memory.

ribbon is in Oasis. The description of ribbon is "[if unvisited]a ribbon[else]Linda's ribbon[end if]".

The target of ribbon is Grotto. The home of ribbon is Ocean.

The realization of the ribbon is "The water around you vanishes and is replaced with your daughter's bedroom... Linda's room. This ribbon was hers. Light blue and wide, a plain strip. Linda was happy, even reckless. Always reading two books at once, changed majors every year. ".

an olive envelope is a green memory. Understand "letter" as olive envelope.

envelope is in Grassy Tuft. The description of envelope is "[if unvisited]an envelope[else]your acceptance letter[end if]".

The target of envelope is Manic Sky. The home of envelope is Fields.

The realization of envelope is "The grasslands fade away and are replaced by a writing room. The envelope held your acceptance letter for your first novel. A horror story about wolves. After Linda first started going to elementary school, you wrote a page a morning, for months.".

an ashen robe is a white memory.

robe is in Grassland. The description of robe is "[if unvisited]a robe[else]your robe[end if]".

The target of robe is Ice Floes. The home of robe is Snow.

The realization of the robe is "The tundra vanishes and is replaced by a small frozen pond where you once skated. This robe was yours as a girl, you dug it out of the cedar chest and started wearing it again when you got sick. You were just wearing it, a few hours ago, before you became this, whatever you are.".

Before taking a memory:

if location of the player is in an unfinished region, say "You try to get the [noun] but it slips away from you. This area needs you to get its memory and focus on it." instead.

Before examining a memory:

say "A memory of [run paragraph on]".

After examining a memory that is not held:

say "(You could pick it up).";

continue the action.

After taking a memory for the first time:

say "Taken.[paragraph break]You've picked up a memory. To connect with it, type 'FOCUS ON [noun]'.".

After printing the name of a visited memory while taking inventory:

say " [i](remembered)[/i]".