further — 10 of 11
Will Hines
Chapter 5 - Help
A person can be travelled or untravelled. The player is untravelled.
After the player going from Foggy Room:
now the player is travelled;
continue the action.
Helping is an action applying to nothing.
Understand "help" and "hint" as helping.
Carry out helping:
if the player is untravelled:
say "Try wandering and reading the room descriptions. There aren't that many rooms and there's nowhere you can get stuck.";
else if the number of memories carried by the player is zero:
say "You need to pick things up (GET them) and examine them (X them).";
else if the number of visited memories is zero:
say "Each thing you can pick up is a memory. Each memory corresponds to a particular room. Bring a memory to its room and FOCUS ON it.";
else if the number of visited memories is less than five:
say "There are five memories you must focus on.";
else if the number of visited memories is five and Cement Room is unvisited:
say "When you focused on the robe, a staircase appeared in the Ice Floes. Cross it.";
else if the player is in Spinning Expanse and Spinning Expanse is not clear:
say "You're in the final room. You must FOCUS ON something unexpected. It's not something you've picked up.";
else if the player is in Spinning Expanse and Spinning Expanse is clear:
say "You've remembered all you need to, and now you just have to leave. A door appeared when you focused on yourself.";
else:
say "Pick up memories, get them to the rooms where they belong and FOCUS ON them.";
Report helping:
say "If you want the longish description of how to play text adventures, type BIG HELP.".
Bighelping is an action applying to nothing.
Understand "more" and "big help" as bighelping.
Carry out bighelping:
say "You are the spirit of someone who just died. You are wandering in a dreamscape figuring how to proceed to the afterlife.[para]If you've never played interactive fiction, here's how:[para]To walk around, type the abbreviation for compass directions and hit enter. Like N, S, E, W, NE, SW, etc. You will move to a new place and the game will describe it.[para]Lots of the game is observing things. You type LOOK and hit enter to get a description of the place you are currently in. And you type EXAMINE or X followed by a thing to get more info on that thing. Like X BELL. Examine everything.[para]You also need to pick things up. Like GET BELL. You can also DROP things though you don't need to.[para]Type I or INVENTORY to see what you're holding.[para]This game has memories which you pick up. Each memory has a room where it belongs. When you're holding a memory in its room you can FOCUS ON it to learn something.[para]At any time, typing HELP will give you a hint.[para]When you don't know what else to do, type LOOK and press enter to make the game re-describe the room you're currently in. Try that now.".
Instead of helping the first time, try bighelping.
Abouting is an action applying to nothing.
Understand "about" and "credits" as abouting.
Carry out abouting:
say "'Further' is about a spirit of someone who recently died trying to gain strength to depart. I wrote it in two sessions 1) riding a train at night and listening to The Postal Service, and 2) a follow-up all-nighter during which I listened to nothing but consumed at least five SIGG bottles of water.[paragraph break]Inform 7 is great fun. My name is Will Hines. I'm an actor/writer person born in 1970 who lives in NYC. My email address is a gmail address: whines.[para]Thanks to beta testers: Benjamin Apple, Andrew Chang, Charone Frankel, Avery Monsen, Brad Temple and Andrew Schultz! And thanks to Andrew Plotkin and Zarfhome Software for the XCode files to turn a z-machine text adventure into an iPhone app (the jargon density of this sentence is insane). ";
Walkthru is an action applying to nothing.
Understand "walkthrough" and "walkthru" and "walk through" and "walk thru" as walkthru.
Carry out walkthru:
say "Below is a walkthrough. It's also available at http://www.willhines.net/if/further[para]
GET BELL[br]
E[br]
D[br]
FOCUS ON BELL[br]
SE[br]
GET PENNY[br]
NW[br]
U[br]
W[br]
W[br]
S[br]
FOCUS ON PENNY[br]
SW[br]
GET RIBBON[br]
NE[br]
N[br]
E[br]
S[br]
D[br]
FOCUS ON RIBBON[br]
SE[br]
GET OLIVE[br]
NW[br]
U[br]
N[br]
N[br]
NW[br]
FOCUS ON OLIVE[br]
W[br]
GET ROBE[br]
E[br]
SE[br]
S[br]
NE[br]
NE[br]
FOCUS ON ROBE[br]
U[br]
FOCUS ON BELL[br]
N[br]
FOCUS ON PENNY[br]
N[br]
FOCUS ON RIBBON[br]
N[br]
FOCUS ON OLIVE[br]
N[br]
FOCUS ON ROBE[br]
N[br]
FOCUS ON SELF[br]
N.".