Harold Night 2003 — 27 of 27

Will Hines

Release 16

Part 8 - Cheating and Ghosts

Xyzzying is an action applying to nothing.

Understand "xyzzy" as Xyzzying.

Carry out xyzzying:

now YesAnding is unused; [to end Beat, if player was in Beat]

now all teachers are warm;

now the player is holding all improv moves;

now all the teachers are bitted;

now all improv moves are known;

now the player holds the skull;

now the player is in Backstage.

Before xyzzying:

say "There's a flash! Suddenly, you know all the improv moves, are holding a magical item and are backstage -- ready to do improv on the stage, which is to the south. (Congrats, interactive fiction nerd).";

continue the action.

Plughing is an action applying to nothing.

Understand "plugh" as Plughing.

Carry out plughing:

say "A hollow voice says 'nerd!'"

Timmying is an action applying to nothing.

Understand "Timmy" or "Wood" or "Tim Wood" or "tim" or "Timmy Wood" or "fook" or "dah fook" as Timmying.

Carry out Timmying:

let r be the next row to use in the fooklist;

choose row r in the Table of Fook;

say "There's a warm flash! The ghost of Timmy Wood appears before you, says '[timmyism entry][no line break]' and then vanishes. You smile."

fooklist is a cyclic list controller.

The associated list is the Table of Fook.

Table of Fook

timmyism
“Suck it down, Charlie Brown!”
“Check, please!”
“One more picky for my ticky”
“Dah Fook?"

Part 9 - Listing Exits, Formatting

When play begins:

now right hand status line is "Exits:[exit list]";

now left hand status line is "[location]".

To say exit list:

let place be location;

repeat with way running through directions:

let place be the room way from the location;

if place is a room:

if place is not Arena or location is Backstage:

choose row with a heading of the way in the Table of Abbreviation;

say "[shortcut entry] ".

Table of Abbreviation

heading		shortcut

north		"N"

northeast		"NE"

northwest		"NW"

east		"E"

southeast		"SE"

south		"S"

southwest		"SW"

west		"W"

up		"U"

down		"D"

inside		"in"

outside		"out"

To say i -- beginning say_i -- running on: (- style underline; -).

To say /i -- ending say_i -- running on: (- style roman; -).

To say b -- beginning say_b -- running on: (- style bold; -).

To say /b -- ending say_b -- running on: (- style roman; -).

To say para -- running on:

(- DivideParagraphPoint(); new_line; -).

To say br -- running on:

(- new_line; -).

Part 10 - Help

Introing is an action applying to nothing.

Carry out introing:

say "You are an improv student at the UCB Theatre in 2003. Find 8 teachers, get each of them to teach you an improv lesson, then find your improv team and then do a scene on the UCB stage.";

Recapping is an action applying to nothing.

Understand "recap" as recapping.

Carry out recapping:

say "[b]LOOK[/b]: describes the current room.[line break][b]N, S, E, W, U or D[/b] move you from room to room. Exits from the current room are listed in the upper right hand corner.[line break][b]GET[/b] gifts (like GET SWORD) and then [b]GIVE[/b] them to teachers (GIVE SWORD TO BILLY) to learn lessons.[line break][b]I[/b] for inventory shows what you're holding and what lessons you've learned.[line break][b]X[/b] is to examine things, like [b]X SWORD[/b] You can X anything: things, people, etc...[line break][b]DO BITS WITH[/b] people to get more clues. Do it more than once.[line break][b]HINT[/b] gives a hint.[line break][b]RESTART[/b] starts over.[line break][b]RECAP[/b] prints this.[line break][b]SCORE[/b] tells you your score. Yes, we keep score though it doesn't matter.[line break]Many other commands work too (JUMP, OPEN, WASH HANDS), but they aren't necessary.[paragraph break]Find all 8 teachers, get improv lessons, then go to the stage (which you have to find) and do improv."

Abouting is an action applying to nothing.

Understand "about" or "credits" as abouting.

Carry out abouting:

let folks be the list of all people who are not part of The Lament;

sort folks in random order;

say "This was written in 2013 by me, Will Hines, who has performed and taught at UCBT in New York since 2000. It was (fellow UCB performer) Neil Casey's idea, and originally was going to be playable only by establishing a telnet connection to ucb's website, which is a sentence few of you will understand or care about.[para]The geography of the theatre is pretty accurate EXCEPT that I made NORTH point towards the stage (in reality, it's EAST) because it made the map (if you draw one) look a bit more sensible. All opinions and characterizations are the author's. If you have suggestions or questions, contact him at his gmail address, of which his handle is whines.[para]Thanks for the help testing from: J.D. Amato, Eva Anderson, Benjamin Apple, Neil Casey, Andrew Chang, Adam Conover, Ramsey Ess, Charone Frankel, Chris Griswold, Susan Hale, Clif Henning, Rory Kulz, Dan Maher, James McCarthy, Avery Monsen, Morgan Phillips, Chris Sarantos, Charlie Todd and Timmy Wood.[para]Thanks to Emily Short and Graham Nelson for the wonderful Inform 7 language .[para]People mentioned in this game (characters who are teachers in this game are boldfaced) [folks].";

helping is an action applying to nothing.

Understand "help", "hint", "hints", "info" as helping.

carry out helping:

if player is in Arena:

say "You are on the stage. Type [b]INITIATE[/b] to do a scene, or else type [b]LOOK[/b] and the game will give you a list of moves you can try.";

else if bar is unvisited:

say "What you need is to get started. Try these three things:[br] Type [b]LOOK[/b] to see the description of your current room.[br] Use compass directions - [b]N, S, E, W, NE, SW[/b] to go to different rooms.[br] [b]EXAMINE[/b] (something) or [b]X[/b] (something) to inspect things and people.";

else if Billy is cold:

say "Billy wants the fake ninja sword. Try [b]GIVE SWORD TO BILLY[/b].";

else if number of known improv moves is 0:

say "Find the bar, where you will find the teacher Billy Merritt. [b]DO BITS WITH Billy[/b]. Start with Billy at the bar.";

else if number of known improv moves is 1:

say "Right now, you just need to explore more. Find gifts and [b]X[/b] them. With teachers, [b]X[/b] them and [b]DO BITS WITH[/b] them.";

else if Box Office is unvisited:

say "Find teacher Matt Besser in the Box Office. To get there from The Bar, go E and then S.";

else if premise is unknown:

say "Besser is interested in promotion which means he's interested in flyers. You've seen a flyer. Give that to him.";

else if Pat Baer is thirsty:

say "Pat Baer in the Tech Booth has something you need. And Pat wants something: he is thirsty.";

else if Performer's Corner is unvisited:

say "You need to find teacher Matt Walsh. Go north through the theater behind the audience to find the Performer's Corner.";

else if if-this-then-what is unknown:

say "Walsh likes The Chicago Bears. Check out the Hot Chicks Room south of the Green Room.";

else if CouchesRoom is unvisited:

say "You need to find teacher Michael Delaney. Check out the rooms in and around the Green Room area, which north of the main theater area.";

else if specificity is unknown:

say "Delaney loves a particular TV show which you can hear him talk about.";

else if Notes is unvisited:

say "You need to find teacher Kevin Mullaney. He is in the rooms that make up the hallways north of the Green Room area.";

else if simplicity is unknown:

say "Mullaney (a teacher) doesn't just love improv. Check the book he's holding. Then go to the room where Besser is.";

else if Chill-Out Room is unvisited:

say "Amy (teacher) is in the Chill-Out Room, northeast of where Mullaney is giving notes.";

else if committing is unknown:

say "Amy is nostalgic for her old improv team from Chicago. Check out the mound of props in the dressing room for something she might like.";

else if MainSeats is unvisited:

say "Ian (teacher) is in the Audience, east of the Back of the House. EXAMINE and DO BITS WITH him to see what he wants";

else if justifying is unknown:

say "Ian likes a particular music artist, which you can deduce from looking at the ticket in his pocket. There's a mix CD in the tech booth.";

else if player is holding skull and truth is unknown:

say "You learned all improv lessons but one. A skull has appeared in your possessions. You must GAZE INTO SKULL.";

else if player is in iO Theatre:

if truth is unknown:

say "Del wants the skull.";

else:

say "Try DO BITS WITH DEL to see what Del wants. Hint: you are holding what he wants.";

else if truth is known:

say "You know all the improv lessons. Get to the stage to do your improv show. If you're having trouble finding the stage, head east from where Pat Baer is.";

else:

say "Go through rooms, examine things, find people and talk, take stuff and give it to others.";

say "[br]([b]RECAP[/b] will remind you of common commands).".

Rule for amusing a victorious player:

say "Have you tried....[para]Smoking pot with Delaney? Others?[br]Turning the knob on the sewer pipe?[br]Warming up? Around different people?[br]Entering the stage from the audience?[br]Examining each team photo in the Lobby?[br]Playing the piano?[br]Checking the scenes on stage when you're in the house?[br]Listening to Mullaney while he gives PCR notes? Or Gethard as he gives Dillinger notes? Repeatedly?[br]Examining PCR, Dillinger, The Lament and each member of those teams and also doing bits with them?[br]Doing bits with everyone you see?[br]Examining the bulletin board?[br]Examining the improv lessons?[br]Clapping? Laughing? [br]Typing 'got your back' when you're backstage?[br]Tried playing cards with anyone besides Mullaney?[br]Doing bits with the skull?[br]Using the bathrooms?[br]Dropping the pot Delaney gives you?[br]Typing the old-school IF mantras XYZZY or PLUGH?[br]finding the 21st point?[br]Examining the audience, and DO BITS WITH each of the Hines Brothers?[br]Typing 'Timmy Wood'?[br]Leaving the UCB history pamphlet in the iO Theatre, then returning to UCB?".

Walkthroughing is an action applying to nothing.

Understand "Walkthrough" and "walkthru" as walkthroughing.

Carry out walkthroughing:

say "TUTORIAL OFF[br]
D[br]
GET SWORD[br]
X PHOTOS[br]
X MONKEYDICK[br]
W[br]
X BILLY[br]
DO BITS WITH BILLY[br]
GIVE SWORD TO BILLY[br]
DO BITS WITH BILLY[br]
GET SODA[br]
W[br]
W[br]
GET FLYER[br]
X FLYER[br]
E[br]
E[br]
N[br]
E[br]
X BESSER[br]
DO BITS WITH BESSER[br]
GIVE FLYER TO BESSER[br]
DO BITS WITH CHUCK[br]
X NEIL[br]
GET CARDS[br]
W[br]
S[br]
W[br]
X STAGE[br]
X AUDIENCE[br]
W[br]
W[br]
W[br]
GET TAPE[br]
N[br]
X PAT[br]
GIVE SODA TO PAT[br]
DO BITS WITH PAT[br]
S[br]
W[br]
N[br]
E[br]
GET FIGURE[br]
W[br]
W[br]
SEARCH MOUND[br]
GET PAINTING[br]
E[br]
N[br]
X DELANEY[br]
GIVE TAPE TO DELANEY[br]
DO BITS WITH DELANEY[br]
SMOKE POT[br]
W[br]
GET TEA[br]
E[br]
S[br]
S[br]
W[br]
N[br]
X MULLANEY[br]
GIVE CARDS TO MULLANEY[br]
DO BITS WITH MULLANEY[br]
LISTEN TO MULLANEY[br]
X PCR[br]
X DIPPOLD[br]
DO BITS WITH SANDERS[br]
NW[br]
X AMY[br]
GIVE PAINTING TO AMY[br]
DO BITS WITH AMY[br]
SE[br]
S[br]
S[br]
LISTEN TO GETHARD[br]
X DILLINGER[br]
X LENNON[br]
DO BITS WITH ERIK[br]
N[br]
E[br]
E[br]
GIVE TEA TO GAUSAS[br]
E[br]
GIVE FIGURE TO WALSH[br]
E[br]
N[br]
X IAN[br]
GIVE CD TO IAN[br]
DO BITS WITH IAN[br]
S[br]
W[br]
W[br]
N[br]
N[br]
E[br]
S[br]
WARM UP[br]
S[br]
I[br]
X SKULL[br]
GAZE INTO SKULL[br]
X DEL[br]
X STUDENTS[br]
GIVE SKULL TO DEL[br]
DO BITS WITH DEL[br]
SE[br]
S[br]
E[br]
E[br]
N[br]
N[br]
E[br]
WARM UP[br]
GOT YOUR BACK[br]
BLURGL[br]
S[br]
INITIATE[br]
BE CONFIDENT[br]
COMMIT[br]
BE SPECIFIC[br]
JUSTIFY[br]
HEIGHTEN[br]
SIMPLIFY[br]
BE TRUTHFUL[br]
BLACKOUT[br]
AMUSING".

Index map with an EPS file and

font set to "Cooper Black",

room-size set to 65,

room-name-size set to 18,

room-name-length set to 40,

map-outline set to off,

room-outline set to off,

title set to "UCB Theatre 2003",

room-colour of Show set to "Black",

room-colour of Prestage set to "Pale Green",

room-colour of Nasty set to "Light Grey",

room-colour of Wires set to "Light Steel Blue",

room-colour of Utility set to "Moccasin",

room-colour of House set to "Orange",

room-colour of Seated set to "Crimson",

room-name of Seated set to "Seats",

room-name-colour of Arena set to "White",

room-name of Performer's Corner set to "Corner",

room-name of Curtain's Edge set to "Curtain",

room-name of BackHouse set to "Back",

room-name of The Bar set to "Bar",

room-name of PianoSpot set to "Piano",

room-name of BathroomsEntrance set to "Corner",

room-name of CouchesRoom set to "Couch",

room-name of Green Room set to "Green",

room-name of Dressing Room set to "Dress",

room-name of OtherDressing set to "Dress",

room-name of Hot Chicks Room set to "Chicks",

room-name of Chill-Out Room set to "Chill",

room-name of Gross Corner set to "Gross",

room-name of Back Hallway set to "Back",

room-name of Vestibule set to "Vest",

room-name of Booth set to "Tech",

room-name of EastBooth set to "Corner",

room-name of Backstage set to "Back",

room-name of BoardRoom set to "Mops",

room-name of Box Office set to "Box",

room-name of Entrance set to "Start",

room-name of The Lobby set to "Lobby",

room-name of Women's Room set to "WR",

room-name of Men's Room set to "MR".