further — 3 of 11

Chapter 2 - Rooms and Regions

Section 1 - The House

A room can be clear or unclear. A room is usually unclear.

A region can be finished or unfinished. A region is usually unfinished.

Before going to a clear room, say "This next room feels more real than the others...".

Before going from a clear room that is not Ice Floes, say "This next room feels more foggy and shapeless...".

A region has a color.

Hazy is a grey finished region. Foggy Room is in Hazy.

Foggy Room is a room. "You no longer exist in a single place, really. But what's left of you tries to make sense of it that way. So it feels like you're in a foggy room. Thick and slow to move through. Exits to the north, south, east, west and northeast.".

After looking when player is untravelled:

say "Type HELP to learn how to play.".

Brick is a red region. Hearth, Wine Cellar and Alcove are in Brick.

Hearth is east of Foggy Room. "This is a room that is made completely of brick. The ceiling, the floors, the walls. Exits are west and also you can go down a brick staircase.".

Wine Cellar is down from Hearth. "[if unclear]A cool brick room with a low ceiling. The walls slowly shift back and forth, as if unreal. There's those stairs heading up and what you perceive to be an alcove to the southeast.[else]This is your basement. No, this WAS your basement, when you were a child. You were a child. A thin carpet. Wood panelling on the walls. A beanbag and black and white TV. Dog toys, for Alice. Red stairs go up and a cubbyhole, made of yellow wood, goes southeast.[end if]".

The printed name of Wine Cellar is "[if unclear]Low Room[else]Your Basement[end if]".

Alcove is southeast of Wine Cellar. "A storage area. The brick floor is interrupted by a smattering of sand, which doesn't seem to belong. Exit to the northwest.".

sand is scenery in Alcove. The description of sand is "A rain puddle's worth of sand, interrupting the brick.".

Desert is a yellow region. Sandstorm, Dunes and Oasis are in Desert.

Sandstorm is west of Foggy Room. "Endless desert. Muted yellow sand whistles by. The dryness is somehow familiar and soothing. Exits east and south.".

Dunes are south of Sandstorm. "[if unclear]Dunes sit serenely here, filled with wisdom. You could go north. There's an unnaturally blue oasis to the southwest.[else]This is Alan's den. His desk with papers in happy, neat piles. There's a doorway north and another southwest. The latter is painted blue.[end if]".

The printed name is "[if unclear]Countless Dunes[else]Alan's Den[end if]".

Oasis is southwest of Dunes. "A deep oasis, nestled here in the otherwise endless sand. Exit to the northeast.".

Ocean is a blue region. Underwater, Grotto and Grassy Tuft are in Ocean.

Underwater is south of Foggy Room. "You are deep underwater, heavy and blue. Exits north and down.".

Grotto is down from Underwater. "[if unclear]A low cave thick with quiet. You can go up. To the southeast, nestled in the sand, is what appears to be a too-small-to-be-normal red chimney.[else]This is Linda's room. Your daughter. It's messy, as she was more like you than Alan. She was happy here, and you were proud that you gave her a happy home. There are stairs up and a hallway to the southeast, painted red.[end if]".

The printed name of Grotto is "[if unclear]Shifting Grotto[else]Linda's Room[end if]".

A room called Grassy Tuft is southeast of Grotto. "A shock of bright green grass sticks up here. The green stands out against the blue. Exit to the northwest.".

Snow is a black region. Tundra and Ice Floes are in Snow.

Tundra is northeast of Foggy Room. "Endless plains of hard snow. Exits southwest and northeast.".

Ice Floes is northeast of Tundra. "[if unclear]The snow gives way to black water, filled with chunks of ice -- each big enough to support several people. An exit is to the southwest.[else]This is the pond where you skated when you were in sixth grade. You kissed a boy here, right by the birch trees. A trail leads out to the southwest. [paragraph break]Also, a beautiful white staircase has appeared. It heads out of the water and... up.[end if]".

The printed name of Ice Floes is "[if unclear]Infinite Ice Floes[else]Frozen Pond[end if]".

Instead of going up from Ice Floes when the player is not white, say "Look at yourself: you're not in the proper state to cross that particular staircase.".

Fields is a green region. Prairie, Manic Sky and Grassland are in Fields.

Prairie is north of Foggy Room. "Flat grassy fields stretch to the horizons. Crisp air. Bright sunlight. Exits south and northwest.".

Manic Sky is northwest of Prairie. "[if unclear]More fields, but here the sky is filled with dogs. Yep, dogs. insanely crowded. Their barks terrify you. A grasslands lies west. Or you can go southeast.[else]This is your writing room. Every morning after your daughter first went to school you'd sit here and write a page. You found yourself while doing that. Exit to the southeast. A grasslands lies to the west.[end if]".

The printed name of Manic Sky is "[if unclear]Manic Sky[else]Your Writing Room[end if]".

Grassland is west of Manic Sky. "A plain grassland, though, oddly, there's patches of snow here and there. Exit to the east.".

[regions]

After looking:

If the location of the player is unclear:

if the player is in Hazy:

say "[i]Haze floats by, carrying a hint of smoke.[/i]";

else if the player is in Ocean:

say "[i]The water is blue and endless.[/i]";

else if the player is in Desert:

say "[i]You feel yellow sand blow by.[/i]";

else if the player is in Brick:

say "[i]Red brick walls and ceilings, the smallest scrape echoes sharply.[/i]";

else if the player is in Fields:

say "[i]There's green grass everywhere.[/i]";

else if the player is in Snow:

say "[i]The snow carries a gleam of white.[/i]";

else if the player is in The Gates:

say "[i]You sense a quiet hum, like from a distant light.[/i]";

continue the action.