Harold Night 2003 — 14 of 27

Section 3 - Tech Booth Area

a thick door is west of Vestibule. a thick door is east of BoardRoom. a thick door is an unlocked, openable door. a thick door is scenery.

Every turn when a thick door was open:

now a thick door is closed;

if the player can see a thick door:

say "The thick door quietly closes, keeping the noise from the Green Room out of the theatre.".

BoardRoom is a room. "This is the first proper backstage room. The green room (where performers change or just hangout) is to the north. The electrical storage area and audience is east. A dingy door leads west into some back hallways. There's also a terminally-ignored bulletin board and like 150 mops here." The printed name of BoardRoom is "Bulletin Board".

Bulletin Board is scenery in BoardRoom. The description of bulletin board is "Lots of things pinned up here, including [one of]an ad for Brett Gelmen and Jon Daly's rap album ('not a bit' is underlined)[or]a bunch of Blondie comic strips, but the final panels are all replaced with the word 'JEWS'[or]instructions for saving choking victims, but photos of various harold team members are pasted over the diagrams[or]a piece of licorice[or]news clipping of Amy getting hired at SNL[cycling].".

Mops are scenery in BoardRoom. The description of mops is "There's seriously like [a random number from 143 to 212] mops here.".

Instead of taking mops, say "No single human could grab all those mops. And if you can't have them all you don't want any.".

A tiny plaque is in BoardRoom. It is fixed in place. The description of tiny plaque is "A small golden plaque embedded in the wall. It reads. 'There is a ghost in this theater. To see him, just say his name.'"

Booth is north of Vestibule. The description of Booth is "This is the tech booth that holds the controls for the lights and speakers of the stage. It's a narrow space, filled with snarls of cords, 1970s-era electronics and an elaborate lighting panel. Back south is a vestibule The stage entrance is towards the north." The printed name of Booth is "Tech Booth".

Pat Baer is an unsmokable male person. He is in Booth. Understand "Pat" and "Baer" as Pat Baer.

Pat can be thirsty or unthirsty. Pat is thirsty.

The description of Pat is "Pat is the tech. He runs the lights and sound for the show. Bearded, bespectacled young man with a Green Lantern t-shirt. He is mumbling to himself about the show on stage. [if thirsty]He's licking his lips, as if he's thirsty.[end if]".

Instead of listening to Pat, say "He's watching the show and shaking his head. You hear him mumble 'These guys just can't play it real!'" instead.

The lighting panel is a supporter which is scenery in Booth. The description of lighting panel is "Lots of sliders for lights and sound. One is marked 'funny' and is pushed all the way up.".

Sliders are scenery in Booth. Instead of pushing or pulling or touching sliders, say "Pat slaps your hand away.".

A mix CD is a gift on the lighting panel. The description of mix CD is "The handwritten label says 'Elvis Costello Get Happy!! Demos'". Understand "mix" and "CD" as mix CD. A mix CD can be wanted or unwanted. The mix CD is unwanted.

Instead of taking mix CD when Pat is thirsty:

if player is holding mix CD:

say "You already have that.";

else:

say "Pat stops you. 'Yeah, that demo's pretty great. I'll trade it to you for a cool soda.'";

now the mix CD is wanted.

Instead of showing the soda to Pat, try giving the soda to Pat.

Instead of giving soda to Pat:

say "Pat happily opens the can and takes a big gulp. 'Ah, that hit the spot. [if mix CD is wanted]You wanted this CD, right? Let me know how it is.'[else]Hey, as a thank you, check out this Elvis Costello CD.'[end if] He gives you the mix CD.";

increase the score by 1;

record "gave a soda to Pat Baer" in the Table of Notes;

now the can of soda is off-stage;

now pat baer is unthirsty;

now the player has the mix CD.

Every turn while player can see Pat Baer:

if Pat is thirsty:

if the player is holding the soda:

say "Pat is eyeing something you're holding.";

else if a random chance of 1 in 3 succeeds:

say "Pat licks his lips and says 'Wish I'd remembered to get a soda before Harold Night started.";

EastBooth is north of Booth. The printed name of EastBooth is "Backstage Corner". "This is the north end of the tech booth, a tight squeeze from the main controls to the south over to the stage curtain -- like right behind the actual stage -- to the east."

A gold brick is in EastBooth. It is fixed in place. The description of gold brick is "A small gold brick is embedded in the wall. Etched into the brick are these words: 'His name is Timmy.'"

Backstage is east from EastBooth and north of the Arena. "You are right behind the stage. You can feel the audience murmuring from through the black curtain which is brushes against your nose and curtains as you fidget. There's tons of graffiti on the backside of the stage wall here. The stage is south on the other side of a thick black curtain, the tech booth is towards the west".

Graffiti is scenery in Backstage. The description of graffiti is "[one of]There's a piece of black electrical tape that says 'Emergency Hitler Mustache'[or]Someone scrawled in crazed red marker: 'DON'T THINK'[or]A drawing of a half-pickle, half-cat labeled unnecessarily 'Picklecat'[or]Thick block letters: 'Dr. Awesome Forever!'[or]Understated green letters: 'Delaney clearly sold his soul.'[or]A medium sized circle with the caption 'Touch here to become funnier.'[or]'Truth in Schmomedy'[cycling]".